blessを使用した例
blessでは、コンストラクタ、プロパティへのアクセスメソッドなどを明示的に定義します。blessを使用したPersonとBaseballPlayerクラス定義は次のようになります。
［リスト2］bless版Person、BaseballPlayerクラス
package blessed::Person;
use strict;
use warnings;
# （1）Personコンストラクタ
sub new {
my $class = shift;
my $self = {
name => 'none',
age => 0,
@_,
};
return bless ($self, $class);
}
# （2）nameプロパティは読み書き可
sub name {
my $self = shift;
if( @_ ) { $self->{name} = shift }
return $self->{name};
}
# （3）ageプロパティは読み込みのみ
sub age {
my $self = shift;
if ( @_ ) { Carp::croak('Cannot assign a value to [age]') }
return $self->{age};
}
# （4）nameとageを表示する自己紹介メソッド
sub introduce {
my $self = shift;
print 'My name is ' , $self->{name} , ', ' , $self->{age} , " years old.\n";
}
1;
# BaseballPlayerクラス
package blessed::BaseballPlayer;
use strict;
use warnings;
# （5）Personから継承
use base qw( blessed::Person );
# （6）BaseballPlayerコンストラクタ
sub new {
my $class = shift;
my $self = blessed::Person->new( team => 'none', @_ );
return bless ($self, $class);
}
sub team {
# 省略
}
#（7）Personのintroduceを呼び出した後に自身の処理を追加
sub introduce {
my $self = shift;
$self->SUPER::introduce();
print "\tAnd I belong to " , $self->{team} , ".\n";
}
1;
blessを使用してクラスを定義した場合には、（1）や（6）のコンストラクタで、引数の処理や継承元クラスの定義などを明示的に記述する必要があります。また、（2）、（3）のプロパティや（4）、（7）のメソッドについても、単体で見るとそれほど難しい実装ではありませんが、数が増えてくると似たような処理を繰り返し書かなければならないことがわかります。
このPersonとBaseballPlayerの動作を確認するスクリプトをblessed_test.plという名前で定義してみます。それとともに実行結果も載せておきます。
［リスト3］blessed_test.pl
use blessed::Person;
use blessed::BaseballPlayer;
# （1）引数を指定してPersonを生成
my $p = blessed::Person->new(name => 'Matsui', age => 35);
print $p->name() , "\n";
print $p->age() , "\n";
# （2）ageは書き込み禁止
#$p->age(18);
# （3）Person::introduceを呼び出し
$p->introduce();
# （4）引数を指定してBaseballPlayerを生成
my $player = blessed::BaseballPlayer->new(
name => 'Suzuki',
age => 36,
team => 'Mariners');
# （5）BaseballPlayer::introduceを呼び出し
$player->introduce();
▼
実行結果
Matsui
35
My name is Matsui, 35 years old.
My name is Suzuki, 36 years old.
And I belong to Mariners.
（1）と（4）では引数を指定してオブジェクトを生成しています。引数で設定したプロパティ値を取得するには、定義してあるアクセスメソッドを呼び出します。例えばnameの値を取得するには$p->name()のように呼び出します。ageプロパティのアクセスメソッドは値の設定を許していないため、（2）のコメントを外すと「Cannot assign a value to [age] at blessed_test.pl line 13」のようなエラーが発生します。（3）と（5）ではintroduceメソッドを呼び出していますが、生成したオブジェクトによって出力される値が異なります。
このスクリプトを実行するには、次のようなコマンドを入力して行います。
［リスト4］blessed_test.plの実行
$ perl blessed_test.pl
